by: Chris Povich
Macintosh Users: For a more readable version download the original lesson in Clarisworks 4.0 or higher.
Topic: Probability from Hands-on to Resampling Stats
Grade Level: Seventh through tenth grade.
NCTM Standards: 1-1 Use, with increasing confidence, problem-solving approaches to investigate and understand mathematical content.
2-3 Express mathematical ideas orally and in writing.
11-3 Use simulations to estimate probabilities.
Goal: My personal goal for this lesson plan was to take two of my favorite activities from The Rice Middle School Mathematics Project and attempt to use the, Resampling Stats, software to work and solve the projects.
Special Note: For this lesson you may need to download the program Resampling Statistics.
Day One:
Activity One: The Hare and the Tortoise Game, adapted from Addison Wesley Publishing. Students will work on the following problem in pairs. (They may use a single six-sided die as recommended, or any other object which produces the same desired probabilities.)
Game Rules
1. The tortoise and the hare start each turn at 0.
2. Each turn consists of three moves. The player will roll a die a total of three times per turn. After each roll, the player’s marker is moved one place to the left if the number on the die is odd and one place to the right if the number on the die is even.
3. Scoring: The tortoise gets a point if at the end of the three moves the marker is on position -1 or 1. The hare gets a point if the marker ends at position -3, -2, 0, 2 or 3.
4. Players alternate turns until each has had 16 turns.
5. To start play: Each player rolls a die. The highest number chooses a character, hare or tortoise, and takes the first turn.
Game Board
|
Record Sheet
 |
What is the probability that a player ends at position -3? P(-3) = _________ .
What is the probability that a player ends at position -2? P(-2) = _________ .
What is the probability that a player ends at position -1? P(-1) = _________ .
What is the probability that a player ends at position 0? P( 0) = _________ .
What is the probability that a player ends at position 1? P( 1) = _________ .
What is the probability that a player ends at position 2? P( 2) = _________ .
What is the probability that a player ends at position 3? P( 3) = _________ .
Discussion Groups
Pairs will be paired up to form groups of four. Students will discuss their results among each other in their groups.
What are some other models, besides dice, that could have been used for this game? Explain why they are valid models? Who seemed to win the game most of the time? Why did this happen? What did you notice about positions, -2, 0, and 2? Why is this true? How could the points be rearranged to make the game fair for both? Explain your reasoning.
Activity Two: Students in their groups will now use the five step method, and, Resampling Stats, software to write a program that will model the hare/tortoise game.
1. Model: Resampling Stats Program. Let -1 = move left and 1 = move right.
Why? The p(-1) = p(left) = .5 and p(1) = p(right) = .5.
2. Trial: One trial for both the hare and the tortoise is to move three times each and locate finish location. The resampling stats program will generate 3 numbers (-1 or 1) for each move. Why? One number, -1 or 1, for each move, left or right.
3. Outcome: The outcome will be the location where the hare or tortoise finishes on after completing one trial (-3, -2, -1, 0, 1, 2, 3).
4. Repeat: Steps 2 and 3 16 times for each the hare and the tortoise. Therefore, 32 trials in all will be executed.
5. Probability/Winner: Calculate the probabilities of finishing on each of the locations in all 32 trials: Ex. p(-3) = (# of times hare and tortoise finished on -3)/(# of trials, 32). Add up the points, described in the directions, to determine the winner.
Example of Hare and Tortoise Resampling Stats Program.
copy (-1 -1 -1 1 1 1) roll 'Possibilities for movement
repeat 16 '16 trials for hare
shuffle roll rolls 'Mix up -1, left, & 1, right, movements
generate 3 rolls x 'Generate three movements
sum x hfinish 'Sum 3 moves to locate trial finish
score hfinish harefin 'Score the hare's finish locations
score hfinish finish 'Score hare & tortoise finish locations
end
count harefin = -3 hn3 'Count # times hare finishes at -3
count harefin = -2 hn2 'Count # times hare finishes at -2
count harefin = -1 hn1 'Count # times hare finishes at -1
count harefin = 0 hz 'Count # times hare finishes at 0
count harefin = 1 hp1 'Count # times hare finishes at 1
count harefin = 2 hp2 'Count # times hare finishes at 2
count harefin = 3 hp3 'Count # times hare finishes at 3
add hn3 hn2 hz hp2 hp3 haretot 'Total points for hare
repeat 16 '16 trials for tortoise
shuffle roll rolls 'Mix up -1, left, & 1, right movements
generate 3 rolls y 'Generate three movements
sum y tfinish 'Sum 3 moves to locate trial finish
score tfinish tortfin 'Score the tortoise's finish locations
score tfinish finish 'Score hare & tortoise finish locations
end
count tortfin = -3 tn3 'Count # times tortoise finishes at -3
count tortfin = -2 tn2 'Count # times tortoise finishes at -2
count tortfin = -1 tn1 'Count # times tortoise finishes at -1
count tortfin = 0 tz 'Count # times tortoise finishes at 0
count tortfin = 1 tp1 'Count # times tortoise finishes at 1
count tortfin = 2 tp2 'Count # times tortoise finishes at 2
count tortfin = 3 tp3 'Count # times tortoise finishes at 3
add tn1 tp1 torttot 'Total points for tortoise
add hn3 tn3 n3 '# of finishes for both at -3
add hn2 tn2 n2 '# of finishes for both at -2
add hn1 tn1 n1 '# of finishes for both at -1
add hz tz z '# of finishes for both at 0
add hp1 tp1 p1 '# of finishes for both at 1
add hp2 tp2 p2 '# of finishes for both at 2
add hp3 tp3 p3 '# of finishes for both at 3
divide n3 32 pn3 'Probability of finishing at -3
divide n2 32 pn2 'Probability of finishing at -2
divide n1 32 pn1 'Probability of finishing at -1
divide z 32 pz 'Probability of finishing at 0
divide p1 32 pp1 'Probability of finishing at 1
divide p2 32 pp2 'Probability of finishing at 2
divide p3 32 pp3 'Probability of finishing at 3
histogram harefin tortfin finish 'Distributions hare, tortoise, & both
print pn3 pn2 pn1 pz pp1 pp2 pp3 'Print probabilities of locations
print haretot torttot 'Print scores for hare & tortoise
Results of 16 trials for hare and 16 trials for tortoise.
Start execution.
Vector no. 1: HAREFIN
Bin Cum
Center Freq Pct Pct
--------------------------------------------
-3 4 25.0 25.0
-1 8 50.0 75.0
1 2 12.5 87.5
3 2 12.5 100.0
Note: Each bin covers all values within 0.25 of
its center.
Vector no. 2: TORTFIN
Bin Cum
Center Freq Pct Pct
--------------------------------------------
-3 1 6.2 6.2
-1 9 56.2 62.5
1 5 31.2 93.8
3 1 6.2 100.0
Note: Each bin covers all values within 0.25 of
its center.
Vector no. 3: FINISH
Bin Cum
Center Freq Pct Pct
--------------------------------------------
-3 5 15.6 15.6
-1 17 53.1 68.8
1 7 21.9 90.6
3 3 9.4 100.0
Note: Each bin covers all values within 0.25 of
its center.
PN3 = 0.15625
PN2 = 0
PN1 = 0.53125
PZ = 0
PP1 = 0.21875
PP2 = 0
PP3 = 0.09375
HARETOT = 6
TORTTOT = 14
Successful execution. (5.2 seconds)
Distribution for the 32 finish locations on the game board (16 for the hare and 16 for the tortoise).
 |
Solution: The estimated p(-3) = 0.15625, p(-2) = 0, p(-1) = 0.53125, p(0) = 0, p(1) = 0.21875, p(2) = 0, and the p(3) = 0.09375. Remember, there are 32 trials altogether, but the hare can only score on its 16 trials and likewise, the tortoise can only score on its 16 trials. The hare end up with six points and the tortoise end up with fourteen points. Therefore, the tortoise would be the winner. By using the resampling stats program students can see the distribution and get a clearer picture of what is happening. Also, the number of trials for both the hair and the tortoise can be increased.
Note: There are three histograms in the program. Unfortunately, I cannot figure how to use edit’s cut and paste to get all three histograms of the same run printed on my document. My first histogram lists the finish locations for the hare. The second histogram lists the finish locations for the tortoise. The last histogram, printed above, lists the finish locations for both the hare and tortoise together as one.
Discussion: Students in their groups will explore changing the probabilities of moving left and right in their programs. They will comment on how this changes the problem. Students will also change the number of moves permitted. They will explain how this changes the problem. The number of trials will also be varied.
Assessment: Each group will present to the class their findings for the project. In the presentations, students will discuss alternate models for the project. Students will also explain findings from changes made in their program. Students will demonstrate their changes and create new problems. Presentations and projects will count for group grades.
Day Two:
Activity One: Castle Warwick to Castle Howard Project, adapted from Addison Wesley Publishing. Students will work in groups of four on the following problem. Students are to come up with their own hands-on model to solve the following problem. After each group has had a chance to work on the problem, the class will collect and discuss its data together.
Our hero Molly is trapped at Castle Warwick. The only escape is to reach Castle Howard through a system of canals. The problem is that the system of canals has five gatekeepers, each run by a cranky gatekeeper who shows up for work half the time. So the probability that a gate is open on a given day is one half. The arrows show the way the water flows through the canals.
What is the probability that a water route from Castle Warwick to Castle Howard is open so that Molly can escape on the day chosen? (We assume that our hero will find it if a route is open.)
Diagram
 |
Record Sheet
 |
Activity Two: Students in their groups will now use the five step method, and, Resampling Stats, software to write a program that will model the castle project.
1. Model: Resampling Stats Program. Let 1 = open and 0 = closed. Why? P(1) = p(open) = .5 and p(0) = p(closed) = .5.
2. Trial: Generate five numbers, 1 or 0, and see if their is a path open. Why? There are five gates, one number for each gate. If the gate is open, then the number one is assigned to that gate. If the gate is closed, then the number 0 is assigned to that gate.
3. Outcome: Check to see if there is a clear path open for the hero, Molly, to escape through. If so, the outcome is, “open.” If there is no open escape route, then the outcome is, “closed.”
4. Repeat: Steps 2 and 3 twenty times.
5. Probability: In the end calculate the probability of escaping or the probability that a gate is open = (# of “open” outcomes) / (# of trials, 20). Also, calculate the probability that there is no escape route available = (# of “closed” outcomes) / (# of trials, 20), or simply, 1- p(“open”).
Example of Castle Resampling Stats Program.
copy (1 1 1 0 0 0) gate 'Set 1 for open and 0 for closed
repeat 20 'Run 20 trials
shuffle gate gates 'Shuffle options
generate 1 gates one 'Open or close gate one
generate 1 gates two 'Open or close gate two
generate 1 gates three 'Open or close gate three
generate 1 gates four 'Open or close gate four
generate 1 gates five 'Open or close gate five
set 1 0 pass 'Our hero has no escape route yet
if two = 1 'Check if gate two is open
if five = 1 'Check if gate five is open
add pass 1 pass 'Escape route found
end
end
if pass = 0 'If no escape route found, continue
if three = 1 'Check if gate three is open
if four =1 'Check if gate four is open
add pass 1 pass 'Escape route found
end
end
end
if pass = 0 'If no escape route found, continue
if one = 1 'Check if gate one is open
if five = 1 'Check if gate five is open
add pass 1 pass 'Escape route found
end
end
end
if pass = 0 'If no escape route found, continue
if one =1 'Check if gate one is open
if four = 1 'Check if gate four is open
add pass 1 pass 'Escape route found
end
end
end
score pass escape 'Score open or closed escape routes
end
sum escape open 'Sum up # times hero escapes
subtract 20 open closed 'Calculate # times hero doesn't escape
divide open 20 popen 'Probability hero escapes
divide closed 20 pclosed 'Probability hero doesn't escape
histogram escape 'Distribution of open & closed routes
print popen pclosed 'Print prob's escaping & not escaping
Results of twenty trials.
Start execution.
Vector no. 1: ESCAPE
Bin Cum
Center Freq Pct Pct
--------------------------------------------
0 8 40.0 40.0
1 12 60.0 100.0
Note: Each bin covers all values within 0.025
of its center.
POPEN = 0.6
PCLOSED = 0.4
Successful execution. (1.8 seconds)
Distribution of the number of times Molly was able to escape (0 - closed path, 1 - open path).
 |
Solution: From the sample run from the above program, out of trials there were 12 “open” and 8 “closed” outcomes. Therefore, the estimated probability of escaping is 0.6. The estimated probability of not escaping is 0.4.
Assessment: Students will write their programs in their journals. They will give a line-by-line explanation of their program’s execution. They will then discuss the advantages and disadvantages to using the, Resampling Stats, software compared to different hands-on models. Students will be encouraged to change the probabilities of the gates being opened, the number of gate and canals, the number of trials, and report their findings. Students will also develop a related problem of interest through the previous explorations. The castle project will count as a part of the student’s journal grade.
Note: I was able to use, Resampling Stats, for other probability problems and projects. Two things I had problems with, though. I wrote an infinite loop and the “escape” key did NOT break the loop. And the second problem I mentioned earlier, if you have more than one histogram it seems like it is not possible to cut and paste all of them at once. Therefore, when I come back to the, Resampling Stats program, after pasting one histogram in a document, the histograms are gone. I know you can save the, “results,” but I can’t save the histograms. When I try to save the histograms, and later open them up, they are distorted. So, it seems like I could only put one histogram from one particular run into my document at a time.